blob: 72ebd61385e1a362368f61426d8c4b8d284ffb21 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
" Only do this when not done yet for this buffer
" Also do nothing if 'compatible' enabled
if exists('b:did_ftplugin_sh_check') || &compatible
finish
endif
let b:did_ftplugin_sh_check = 1
if exists('b:undo_ftplugin')
let b:undo_ftplugin = b:undo_ftplugin
\ . '|unlet b:did_ftplugin_sh_check'
endif
" Choose checker based on shell family
if exists('b:is_bash')
let b:sh_check_makeprg = 'bash -n %:S'
elseif exists('b:is_kornshell')
let b:sh_check_makeprg = 'ksh -n %:S'
else
let b:sh_check_makeprg = 'sh -n %:S'
endif
let b:sh_check_errorformat = '%f: %l: %m'
if exists('b:undo_ftplugin')
let b:undo_ftplugin = b:undo_ftplugin
\ . '|unlet b:sh_check_makeprg'
\ . '|unlet b:sh_check_errorformat'
endif
" Build function for checker
if !exists('*s:ShCheck')
function s:ShCheck()
let l:save_makeprg = &l:makeprg
let l:save_errorformat = &l:errorformat
let &l:makeprg = b:sh_check_makeprg
let &l:errorformat = b:sh_check_errorformat
lmake!
let &l:makeprg = l:save_makeprg
let &l:errorformat = l:save_errorformat
lwindow
endfunction
endif
" Set up a mapping for the checker, if we're allowed
if !exists('g:no_plugin_maps') && !exists('g:no_sh_maps')
" Define a mapping target
nnoremap <buffer> <silent> <unique>
\ <Plug>ShCheck
\ :<C-U>call <SID>ShCheck()<CR>
if exists('b:undo_ftplugin')
let b:undo_ftplugin = b:undo_ftplugin
\ . '|nunmap <buffer> <Plug>ShCheck'
endif
" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>ShCheck')
nmap <buffer> <unique>
\ <LocalLeader>c
\ <Plug>ShCheck
if exists('b:undo_ftplugin')
let b:undo_ftplugin = b:undo_ftplugin
\ . '|nunmap <buffer> <LocalLeader>c'
endif
endif
endif
|