"
" put_blank_lines.vim: Provide plugin maps to put blank lines above or below
" the current line. The guts of this is backported from Tim Pope's
" unimpaired.vim plugin, and still uses repeat.vim if it can find it.
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" License: Same as Vim itself
"
if exists('g:loaded_put_blank_lines') || &compatible
  finish
endif
if v:version < 600
  finish
endif
let g:loaded_put_blank_lines = 1

function! s:PutBlankLinesAbove(count)
  let l:i = 0
  while l:i < a:count
    silent put! =nr2char(10)
    let l:i = l:i + 1
    ']+1
  endwhile
  silent! call repeat#set("\<Plug>(PutBlankLinesAbove)", a:count)
endfunction

function! s:PutBlankLinesBelow(count)
  let l:i = 0
  while l:i < a:count
    silent put =nr2char(10)
    let l:i = l:i + 1
    '[-1
  endwhile
  silent! call repeat#set("\<Plug>(PutBlankLinesBelow)", a:count)
endfunction

nnoremap <silent> <unique>
      \ <Plug>(PutBlankLinesAbove)
      \ :<C-U>call <SID>PutBlankLinesAbove(v:count1)<CR>

nnoremap <silent> <unique>
      \ <Plug>(PutBlankLinesBelow)
      \ :<C-U>call <SID>PutBlankLinesBelow(v:count1)<CR>