blob: ac0f3cf6e9a9b27ea3d5769038b1b3f228be3eff (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
"
" copy_linebreak.vim: Bind user-defined key sequences to toggle a group of
" options that make text wrapped with 'wrap' copy-paste friendly.
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" License: Same as Vim itself
"
if exists('loaded_copy_linebreak') || &compatible || v:version < 700
finish
endif
let loaded_copy_linebreak = 1
" Enable copy-friendly linebreak options
function! s:CopyLinebreakEnable()
setlocal nolinebreak linebreak?
let s:showbreak_save = &showbreak
set showbreak=
if exists('+breakindent')
setlocal nobreakindent
endif
endfunction
" Disable copy-friendly linebreak options
function! s:CopyLinebreakDisable()
setlocal linebreak linebreak?
if exists('s:showbreak_save')
let &showbreak = s:showbreak_save
unlet s:showbreak_save
endif
if exists('+breakindent')
setlocal breakindent<
endif
endfunction
" Toggle copy-friendly linebreak options, using the current setting for the
" 'linebreak' option as the pivot
function! s:CopyLinebreakToggle()
if &linebreak
call s:CopyLinebreakEnable()
else
call s:CopyLinebreakDisable()
endif
endfunction
" Provide mappings to the functions just defined
noremap <silent>
\ <Plug>(CopyLinebreakEnable)
\ :<C-U>call <SID>CopyLinebreakEnable()<CR>
noremap <silent>
\ <Plug>(CopyLinebreakDisable)
\ :<C-U>call <SID>CopyLinebreakDisable()<CR>
noremap <silent>
\ <Plug>(CopyLinebreakToggle)
\ :<C-U>call <SID>CopyLinebreakToggle()<CR>
|