aboutsummaryrefslogtreecommitdiff
path: root/vim/plugin/undoskip.vim
blob: ffbabf866325c490ebadcdbe621d80f1431967a7 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
"
" undoskip.vim: Don't save undo history for temporary or secure files.
"
" Author: Tom Ryder <tom@sanctum.geek.nz>
" License: Same as Vim itself
"
if exists('loaded_undoskip') || &compatible || !has('persistent_undo')
  finish
endif
let loaded_undoskip = 1

" Set the paths to test; can be changed by the user
let g:undoskip_patterns = ['^/dev/shm/.', '^/tmp/.', '^/var/tmp/.']

" Internal function returns a local value for 'undofile'
function s:CheckUndoSkip() abort

  " If this isn't a normal buffer, don't save undo data
  if &buftype !=# ''
    return 0
  endif

  " Get the path from the buffer name; if that path matches any of the
  " patterns, don't save undo data
  let path = bufname('%')
  for pattern in g:undoskip_patterns
    if path =~# pattern
      return 0
    endif
  endfor

  " Otherwise, we'll use whatever the global setting is
  return &g:undofile

endfunction

" Command interface into the private function's value, does the actual set
command -nargs=0 CheckUndoSkip
      \ let &l:undofile = s:CheckUndoSkip()

" Check the path on every buffer rename, create, or read
augroup undoskip
  autocmd!
  autocmd BufAdd,BufNewFile,BufRead *
        \ CheckUndoSkip
augroup END