aboutsummaryrefslogtreecommitdiff
path: root/vim/after/ftplugin/sh.vim
blob: 5cafdd7028a8e1658aef297097ada8b9b7e00086 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
" Extra configuration for shell script
if &filetype != 'sh' || &compatible || v:version < 700
  finish
endif

" Set comment formats
setlocal comments=:#
setlocal formatoptions+=or
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|setlocal comments<'
      \ . '|setlocal formatoptions<'

" If subtype is Bash, set 'keywordprg' to han(1df)
if exists('b:is_bash')
  setlocal keywordprg=han
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|setlocal keywordprg<'
endif

" Choose check compiler based on file subtype
if exists('b:is_bash')
  let b:sh_check_compiler = 'bash'
elseif exists('b:is_kornshell')
  let b:sh_check_compiler = 'ksh'
else
  let b:sh_check_compiler = 'sh'
endif
execute 'compiler '.b:sh_check_compiler
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:current_compiler'
      \ . '|unlet b:sh_check_compiler'
      \ . '|setlocal errorformat<'
      \ . '|setlocal makeprg<'

" Stop here if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_sh_maps')
  finish
endif

" Mappings to choose compiler
nnoremap <buffer> <expr> <LocalLeader>c
      \ ':<C-U>compiler '.b:sh_check_compiler.'<CR>'
nnoremap <buffer> <LocalLeader>l
      \ :<C-U>compiler shellcheck<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <LocalLeader>c'
      \ . '|nunmap <buffer> <LocalLeader>l'