1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Ha, ha, ha! Awk!
# Process arguments
BEGIN {
# If no arguments left, assume a dictionary file
if (ARGC == 1) {
ARGC = 2
if ("DICT" in ENVIRON)
ARGV[1] = ENVIRON["DICT"]
else
ARGV[1] = "/usr/share/dict/words"
}
# Seed the random number generator
rnds = "rnds 2>/dev/null"
rnds | getline seed
close(rnds)
if (length(seed))
srand(seed + 0)
else
srand()
}
# Iterate over the lines, randomly assigning the first field of each one with a
# decreasing probability; this method allows a single pass over the input,
# though it requires a lot of random numbers
$1 ~ /[a-zA-Z]/ && rand() * ++n < 1 { wr = $1 }
# Ha, ha! Conclusion!
END {
# Check that we processed at least one line
if (!NR)
exit 1
# Strip trailing possessives and punctuation
sub(/[^a-zA-Z]+s*$/, "", wr)
# Two or three "ha"s? Important decisions here folks
hr = int(rand()*2+1)
for (ha = "Ha"; hi < hr; hi++)
ha = ha ", ha"
# Capitalise the word
wr = toupper(substr(wr,1,1)) substr(wr,2)
# Print the laughter and the word
printf "%s! %s!\n", ha, wr
}
|