" Don't make any effort to be compatible with vi, use more sensible settings.
" This is only here in case this file gets loaded explicitly with -u; the mere
" existence of a ~/.vimrc file already turns this off.
set nocompatible

" Use UTF-8 by default wherever possible, including in this file
if has('multi_byte')
  set encoding=utf-8
  scriptencoding utf-8
endif

" Load configuration files from ~/.vim/config or its analogue, before Pathogen
" loads all its directories into 'runtimepath'
runtime! config/*.vim

" If our version isn't ancient and Pathogen is available, call it to load all
" the plugins in .vim/bundle; these are saved as submodules
if v:version >= 701

  " Bootstrap Pathogen
  runtime bundle/pathogen/autoload/pathogen.vim

  " Run Pathogen to broaden 'realtimepath' for plugin code and help tags
  silent! call pathogen#infect()
  silent! call pathogen#helptags()

  " The 'sahara' colorscheme only works for dark backgrounds with 256 colors
  if has('syntax')
        \ && &background == 'dark'
        \ && (has('gui_running') || &t_Co == 256)
    silent! colorscheme sahara
  endif
endif