From a03e011345413a9b3749deb9da895bb4e8ec9974 Mon Sep 17 00:00:00 2001
From: Tom Ryder <tom@sanctum.geek.nz>
Date: Sat, 3 Dec 2016 02:02:16 +1300
Subject: Rewrite unf(1df) in awk

Also update manual page references to it, and improve it by making it
ignore body content
---
 bin/unf.awk | 34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 bin/unf.awk

(limited to 'bin/unf.awk')

diff --git a/bin/unf.awk b/bin/unf.awk
new file mode 100644
index 00000000..22a10aa8
--- /dev/null
+++ b/bin/unf.awk
@@ -0,0 +1,34 @@
+# Unfold header lines in an internet message, don't touch the body
+
+# Function to write and empty the buffer
+function wrbuf() {
+    if (length(buf))
+        print buf
+    buf = ""
+}
+
+# Flag to stop processing once we hit the first blank line
+!length {
+    wrbuf() 
+    body = 1
+}
+body {
+    print
+    next
+}
+
+# Write any buffer contents once we hit a line not starting with a space
+/^[^ \t]/ {
+    wrbuf()
+}
+
+# Append the current line to the buffer
+{
+    sub(/^[ \t]+/, " ")
+    buf = buf $0
+}
+
+# Write the buffer out again when we hit the end
+END {
+    wrbuf()
+}
-- 
cgit v1.2.3