aboutsummaryrefslogblamecommitdiff
path: root/vim/after/ftplugin/perl/lint.vim
blob: eaa6684c69049d6336467a0b4e52647b65f7c40c (plain) (tree)
1
2
3
4
5
6
7
8
9
10



                                                 

        



                                     
     
 




                                                         




                                           


                                   
                                                  

                                           




                                                         
                        

                                             
     
" perl/lint.vim: Use Perl::Critic to lint scripts

" Don't load if running compatible or too old
if &compatible || v:version < 700
  finish
endif

" Don't load if already loaded
if exists('b:did_ftplugin_perl_lint')
  finish
endif

" Don't load if the user doesn't want ftplugin mappings
if exists('g:no_plugin_maps') || exists('g:no_html_maps')
  finish
endif

" Flag as loaded
let b:did_ftplugin_perl_lint = 1
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|unlet b:did_ftplugin_perl_lint'

" Define a mapping target
nnoremap <buffer> <silent> <unique>
      \ <Plug>PerlLint
      \ :<C-U>call compiler#Make('perlcritic')<CR>
let b:undo_ftplugin = b:undo_ftplugin
      \ . '|nunmap <buffer> <Plug>PerlLint'

" If there isn't a key mapping already, use a default one
if !hasmapto('<Plug>PerlLint')
  nmap <buffer> <unique>
        \ <LocalLeader>l
        \ <Plug>PerlLint
  let b:undo_ftplugin = b:undo_ftplugin
        \ . '|nunmap <buffer> <LocalLeader>l'
endif